1: /*
   2:  *	SCCS id	@(#)hk7boot.s	2.0 (2.11BSD)	4/13/91
   3:  */
   4: #include "localopts.h"
   5: 
   6: /  The boot options and device are placed in the last SZFLAGS bytes
   7: /  at the end of core for the bootstrap.
   8: ENDCORE=        160000          / end of core, mem. management off
   9: SZFLAGS=        6               / size of boot flags
  10: BOOTOPTS=       2               / location of options, bytes below ENDCORE
  11: BOOTDEV=        4               / boot unit
  12: CHECKWORD=      6
  13: 
  14: .globl  _doboot, hardboot, _bootcsr
  15: .text
  16: _doboot:
  17:         mov     4(sp),r4        / boot options
  18:         mov     2(sp),r3        / boot device
  19: 
  20: #ifndef KERN_NONSEP
  21: /  If running separate I/D, need to turn off memory management.
  22: /  Call the routine unmap in low text, after setting up a jump
  23: /  in low data where the PC will be pointing.
  24: .globl  unmap
  25:         mov     $137,*$unmap+2          / jmp *$hardboot
  26:         mov     $hardboot,*$unmap+4
  27:         jmp     unmap
  28:         / "return" from unmap will be to hardboot in data
  29: .data
  30: #else
  31: /  Reset to turn off memory management
  32:         reset
  33: #endif
  34: 
  35: /  On power fail, hardboot is the entry point (map is already off)
  36: /  and the args are in r4 (RB_POWRFAIL), r3 (rootdev)
  37: 
  38: hardboot:
  39:         mov     r4, ENDCORE-BOOTOPTS
  40:         ash     $-3,r3          / shift out the partition number
  41:         bic     $!7,r3          / save only the drive number
  42:         mov     r3, ENDCORE-BOOTDEV
  43:         com     r4              / if CHECKWORD == ~bootopts, flags are believed
  44:         mov     r4, ENDCORE-CHECKWORD
  45: 1:
  46:         reset
  47: 
  48: /  The remainder of the code is dependent on the boot device.
  49: /  If you have a bootstrap ROM, just jump to the correct entry.
  50: /  Otherwise, use a BOOT opcode, if available;
  51: /  if necessary, read in block 0 to location 0 "by hand".
  52: 
  53: / rk07 disk driver
  54: 
  55: WC = -256.
  56: 
  57: hkcs1 = 0       / offsets from base csr, control & status 1
  58: hkda  = 6       / desired track/sector address
  59: hkcs2 = 10      / control & status 2
  60: hkca  = 20      / desired cylinder
  61: 
  62: / RK07 constants
  63: ack = 02003     / pack acknowledge
  64: clear = 040     / subsystem clear
  65: iocom = 2021    / read + go
  66: 
  67: / initialize hk
  68:         mov     _bootcsr,r1
  69:         mov     $clear,hkcs2(r1)
  70:         mov     $ack,hkcs1(r1)
  71: 0:
  72:         tstb    hkcs1(r1)
  73:         bpl     0b              / wait for acknowledge to complete
  74: 
  75:         clr     hkca(r1)
  76:         add     $hkcs2,r1
  77:         mov     ENDCORE-BOOTDEV,(r1)
  78:         clr     -(r1)           / sector and track (hkda)
  79:         clr     -(r1)           / bus address
  80:         mov     $WC,-(r1)       / word count
  81:         mov     $iocom,-(r1)
  82: 1:
  83:         tstb    (r1)
  84:         bge     1b              / wait for iocom to complete
  85:         mov     ENDCORE-BOOTDEV,r0
  86:         clr     pc

Defined functions

BOOTDEV defined in line 11; used 3 times
BOOTOPTS defined in line 10; used 1 times
  • in line 39
CHECKWORD defined in line 12; used 1 times
  • in line 44
ENDCORE defined in line 8; used 5 times
SZFLAGS defined in line 9; never used
_doboot declared in line 14; defined in line 16; used 1 times
  • in line 14

Defined variables

WC defined in line 55; used 1 times
  • in line 80
ack defined in line 63; used 1 times
  • in line 70
clear defined in line 64; used 1 times
  • in line 69
hardboot declared in line 14; defined in line 38; used 2 times
hkca defined in line 60; used 1 times
  • in line 75
hkcs1 defined in line 57; used 2 times
hkcs2 defined in line 59; used 2 times
hkda defined in line 58; never used
iocom defined in line 65; used 1 times
  • in line 81
Last modified: 1991-04-20
Generated: 2016-12-26
Generated by src2html V0.67
page hit count: 879
Valid CSS Valid XHTML 1.0 Strict