1: /*
   2:  *	SCCS id	@(#)dvhpboot.s	2.0 (2.11BSD)	4/13/91
   3:  */
   4: #include "localopts.h"
   5: 
   6: /  The boot options and device are placed in the last SZFLAGS bytes
   7: /  at the end of core for the bootstrap.
   8: ENDCORE=        160000          / end of core, mem. management off
   9: SZFLAGS=        6               / size of boot flags
  10: BOOTOPTS=       2               / location of options, bytes below ENDCORE
  11: BOOTDEV=        4               / boot unit
  12: CHECKWORD=      6
  13: 
  14: .globl  _doboot, hardboot, _bootcsr
  15: .text
  16: _doboot:
  17:         mov     4(sp),r4        / boot options
  18:         mov     2(sp),r3        / boot device
  19: 
  20: #ifndef KERN_NONSEP
  21: /  If running separate I/D, need to turn off memory management.
  22: /  Call the routine unmap in low text, after setting up a jump
  23: /  in low data where the PC will be pointing.
  24: .globl  unmap
  25:         mov     $137,*$unmap+2          / jmp *$hardboot
  26:         mov     $hardboot,*$unmap+4
  27:         jmp     unmap
  28:         / "return" from unmap will be to hardboot in data
  29: .data
  30: #else
  31: /  Reset to turn off memory management
  32:         reset
  33: #endif
  34: 
  35: /  On power fail, hardboot is the entry point (map is already off)
  36: /  and the args are in r4 (RB_POWRFAIL), r3 (rootdev)
  37: 
  38: hardboot:
  39:         mov     r4, ENDCORE-BOOTOPTS
  40:         ash     $-3,r3          / shift out the partition number
  41:         bic     $!7,r3          / save only the drive number
  42:         mov     r3, ENDCORE-BOOTDEV
  43:         com     r4              / if CHECKWORD == ~bootopts, flags are believed
  44:         mov     r4, ENDCORE-CHECKWORD
  45: 1:
  46:         reset
  47: 
  48: /  The remainder of the code is dependent on the boot device.
  49: /  If you have a bootstrap ROM, just jump to the correct entry.
  50: /  Otherwise, use a BOOT opcode, if available;
  51: /  if necessary, read in block 0 to location 0 "by hand".
  52: 
  53: /
  54: / Bootstrap for DIVA Comp/V controller without boot opcode
  55: /
  56: HPCSR=  0               / offset from base csr
  57: HPCS2=  10              / Control/status register 2
  58: HPDC=   34              / Desired cylinder
  59: HPBAE=  50              / Bus extension address (RH70)
  60: READIT= 71
  61: 
  62:         mov     _bootcsr,r1     / boot device csr
  63: 1:
  64:         tstb    (r1)            / wait for ready (HPCSR is offset 0)
  65:         bpl     1b
  66: 
  67:         clr     HPDC(r1)        / Cylinder 0
  68:         clr     HPBAE           / Bus extension address = 0
  69:         add     $HPCS2,r1
  70:         mov     ENDCORE-BOOTDEV,(r1)    / unit number
  71:         clr     -(r1)           / hpda = 0 (desired address 0)
  72:         clr     -(r1)           / hpba = 0 (buf address 0)
  73:         mov     $-256.,-(r1)    / hpwc = -256 (one block)
  74:         mov     $READIT,-(r1)   / hpcs1 = HP_RCOM|HP_GO
  75: 
  76: 1:
  77:         tstb    (r1)            / wait for done
  78:         bpl     1b
  79:         mov     ENDCORE-BOOTDEV,r0
  80:         clr     pc

Defined functions

BOOTDEV defined in line 11; used 3 times
BOOTOPTS defined in line 10; used 1 times
  • in line 39
CHECKWORD defined in line 12; used 1 times
  • in line 44
ENDCORE defined in line 8; used 5 times
SZFLAGS defined in line 9; never used
_doboot declared in line 14; defined in line 16; used 1 times
  • in line 14

Defined variables

HPBAE defined in line 59; used 1 times
  • in line 68
HPCS2 defined in line 57; used 1 times
  • in line 69
HPCSR defined in line 56; never used
HPDC defined in line 58; used 1 times
  • in line 67
READIT defined in line 60; used 1 times
  • in line 74
hardboot declared in line 14; defined in line 38; used 2 times
Last modified: 1991-04-20
Generated: 2016-12-26
Generated by src2html V0.67
page hit count: 700
Valid CSS Valid XHTML 1.0 Strict