1: /*
   2:  *	SCCS id	@(#)boot.s	1.2 (Berkeley)	9/6/82
   3:  */
   4: #include "whoami.h"
   5: 
   6: #ifdef  UCB_AUTOBOOT
   7: /  The boot options and device are placed in the last SZFLAGS bytes
   8: /  at the end of core for the bootstrap.
   9: ENDCORE=        160000          / end of core, mem. management off
  10: SZFLAGS=        6               / size of boot flags
  11: BOOTOPTS=       2               / location of options, bytes below ENDCORE
  12: BOOTDEV=        4
  13: CHECKWORD=      6
  14: 
  15: reset=  5
  16: 
  17: .globl  _doboot, hardboot
  18: .text
  19: _doboot:
  20:         mov     4(sp),r4        / boot options
  21:         mov     2(sp),r3        / boot device
  22: 
  23: #ifndef KERN_NONSEP
  24: /  If running separate I/D, need to turn off memory management.
  25: /  Call the routine unmap in low text, after setting up a jump
  26: /  in low data where the PC will be pointing.
  27: .globl  unmap
  28:         mov     $137,*$unmap+2          / jmp *$hardboot
  29:         mov     $hardboot,*$unmap+4
  30:         jmp     unmap
  31:         / "return" from unmap will be to hardboot in data
  32: .data
  33: #else
  34: /  Reset to turn off memory management
  35:         reset
  36: #endif
  37: 
  38: /  On power fail, hardboot is the entry point (map is already off)
  39: /  and the args are in r4, r3.
  40: 
  41: hardboot:
  42:         mov     r4, ENDCORE-BOOTOPTS
  43:         mov     r3, ENDCORE-BOOTDEV
  44:         com     r4              / if CHECKWORD == ~bootopts, flags are believed
  45:         mov     r4, ENDCORE-CHECKWORD
  46: 1:
  47:         reset
  48: 
  49: /  The remainder of the code is dependent on the boot device.
  50: /  If you have a bootstrap ROM, just jump to the correct entry.
  51: /  Otherwise, use a BOOT opcode, if available;
  52: /  if necessary, read in block 0 to location 0 "by hand".
  53: 
  54: /  Bootstrap for rl01/02 drive - salkind@nyu
  55: 
  56: WC      = -256.
  57: READ    = 6\<1
  58: SEEK    = 3\<1
  59: RDHDR   = 4\<1
  60: 
  61: rlcs    = 174400
  62: rlda    = 174404
  63: rlba    = 174402
  64: rlmp    = 174406
  65: 
  66:         mov     $RDHDR,*$rlcs   /find out where we are (cyl)
  67: 1:
  68:         tstb    *$rlcs
  69:         bpl     1b
  70:         mov     *$rlmp,r0
  71:         bic     $!77600,r0
  72:         bis     $1,r0
  73:         mov     r0,*$rlda
  74:         mov     $SEEK,*$rlcs    / move it
  75: 1:
  76:         tstb    *$rlcs
  77:         bpl     1b
  78: /
  79:         mov     $rlmp,r0
  80:         mov     $WC,(r0)        /wc into rlmp
  81:         clr     -(r0)           /da into rlda
  82:         clr     -(r0)           /ba
  83:         mov     $READ,-(r0)     /cmd into rlcs
  84: 1:
  85:         tstb    *$rlcs
  86:         bpl     1b
  87: /
  88:         jmp     *$0             / and away we go
  89: 
  90: #endif	UCB_AUTOBOOT

Defined functions

BOOTDEV defined in line 12; used 1 times
  • in line 43
BOOTOPTS defined in line 11; used 1 times
  • in line 42
CHECKWORD defined in line 13; used 1 times
  • in line 45
ENDCORE defined in line 9; used 3 times
SZFLAGS defined in line 10; never used
_doboot declared in line 17; defined in line 19; used 1 times
  • in line 17

Defined variables

RDHDR defined in line 59; used 1 times
  • in line 66
READ defined in line 57; used 1 times
  • in line 83
SEEK defined in line 58; used 1 times
  • in line 74
WC defined in line 56; used 1 times
  • in line 80
hardboot declared in line 17; defined in line 41; used 2 times
rlba defined in line 63; never used
rlcs defined in line 61; used 5 times
rlda defined in line 62; used 1 times
  • in line 73
rlmp defined in line 64; used 2 times
Last modified: 1983-03-22
Generated: 2016-12-26
Generated by src2html V0.67
page hit count: 496
Valid CSS Valid XHTML 1.0 Strict